承之前的文章, Linux porting的步驟如下所示
1.根據你的平台和相關硬體,找出一個跟此結構最相似的architecture
2.拷貝這個結構的硬體範本到新結構的目錄下.通常只需拷貝以下幾個資料夾
<1>arch/xxx/mach-xxx
<2>include/arch/xxx/mach-xxx
3.試著編譯新架構並修改相關的define和Kconfig檔案
上面的步驟完成後,你已經有一個新架構的殼在那裡了
接著再談到在新的骨架下填肉的問題,這邊我們所提到的肉,就是IRQ和linux kernel timer
我們先談IRQ在Linux的生死流程
當硬體發出IRQ中斷時,Linux第一個接觸到此中斷的程式是entry-armv.S,這個檔程式負責找出發出IRQ中斷的號碼,並呼叫do_irq這個函式去處理相關的硬體中斷,do_irq函式返回後,entry-armv.S會處理context restored的一些流程,而在這邊我們所需要修改的程式只有entry-macro這隻巨集,此巨具會找到發出中斷的編號
在修改entry-macro.S這隻程式前,我以為取得2410中斷編號的方法應該跟4510一樣簡單,只要讀取interrupt offset這個暫存器就可以了,結果發現並不是那麼一回事,如果entry-macro.S寫得像下面那樣
- .macro get_irqnr_and_base, irqnr, irqstat, base, tmp
- ldr \tmp, =rINTOFFSET
- ldr \irqnr, [\tmp] @ get irq no
- teq \irqnr, #NR_IRQS
- .endm
你會發現你有收不完的EINT0外部中斷,而導製整個系統locking.為什麼呢?因為interrupt offset也有可能沒有值,但卻不是EINT0外部中斷,所以下面這段程式除了檢查interrupt pending之外,還需檢查CPSR的flag是否有設定正確
- #include <asm/arch/map.h>
- #if defined(CONFIG_ARCH_QT2410)
-
- .macro get_irqnr_and_base, irqnr, irqstat, base, tmp
- mov \tmp, #S3C2410_PA_IRQ
- ldr \irqnr, [ \tmp, #0x14 ] @ get irq no
- 30000:
- teq \irqnr, #4
- teqne \irqnr, #5
- beq 1002f @ external irq reg
-
- @ debug check to see if interrupt reported is the same
- @ as the offset....
-
- teq \irqnr, #0
- beq 20002f
- ldr \irqstat, [ \tmp, #0x10 ] @ INTPND
- mov \irqstat, \irqstat, lsr \irqnr
- tst \irqstat, #1
- bne 20002f
-
-
- #if 1
- stmfd r13!, { r0 - r4 , r8-r12, r14 }
- ldr r1, [ \tmp, #0x14 ] @ INTOFFSET
- ldr r2, [ \tmp, #0x10 ] @ INTPND
- ldr r3, [ \tmp, #0x00 ] @ SRCPND
- adr r0, 20003f
- bl printk
- b 20004f
-
- 20003:
- .ascii "<7>irq: err - bad offset %d, intpnd=%08x, srcpnd=%08x\n"
- .byte 0
- .align 4
- 20004:
- mov r1, #1
- mov \tmp, #S3C24XX_PA_IRQ
- ldmfd r13!, { r0 - r4 , r8-r12, r14 }
- #endif
-
- @ try working out interrupt number for ourselves
- mov \irqnr, #0
- ldr \irqstat, [ \tmp, #0x10 ] @ INTPND
- 10021:
- movs \irqstat, \irqstat, lsr#1
- bcs 30000b @ try and re-start the proccess
- add \irqnr, \irqnr, #1
- cmp \irqnr, #32
- ble 10021b
-
- @ found no interrupt, set Z flag and leave
- movs \irqnr, #0
- b 1001f
-
- 20005:
- 20002: @ exit
- @ we base the s3c2410x interrupts at 16 and above to allow
- @ isa peripherals to have their standard interrupts, also
- @ ensure that Z flag is un-set on exit
-
- @ note, we cannot be sure if we get IRQ_EINT0 (0) that
- @ there is simply no interrupt pending, so in all other
- @ cases we jump to say we have found something, otherwise
- @ we check to see if the interrupt really is assrted
- @ Joey:Add 16 to current interrupt number?? It is not necessay for qt2410
- @adds \irqnr, \irqnr, #IRQ_EINT0
- teq \irqnr, #nEXT0_INT
- bne 1001f @ exit
- ldr \irqstat, [ \tmp, #0x10 ] @ INTPND
- teq \irqstat, #0
- moveq \irqnr, #0
- b 1001f
-
- @ we get here from no main or external interrupts pending
- 1002:
- @add \tmp, \tmp, #S3C2410_PA_GPIO - S3C24XX_PA_IRQ
- mov \tmp, #S3C2410_PA_GPIO
- ldr \irqstat, [ \tmp, # 0xa8 ] @ EXTINTPEND
- ldr \irqnr, [ \tmp, # 0xa4 ] @ EXTINTMASK
-
- bic \irqstat, \irqstat, \irqnr @ clear masked irqs
-
- mov \irqnr, #nEXT4_7_INT @ start extint nos
- mov \irqstat, \irqstat, lsr#4 @ ignore bottom 4 bits
- 10021:
- movs \irqstat, \irqstat, lsr#1
- bcs 1004f
- add \irqnr, \irqnr, #1
- cmp \irqnr, #nEXT8_23_INT
- ble 10021b
-
- @ found no interrupt, set Z flag and leave
- movs \irqnr, #0
-
- 1004: @ ensure Z flag clear in case our MOVS shifted out the last bit
- teq \irqnr, #0
- 1001:
- @ exit irq routine
- .endm
-
-
-
-
- .macro disable_fiq
- .endm
-
-
- #endif
修正完entry-macro.S這個檔案後,接著我們要註冊IRQ的處理函式
在arch/arm/mach-qt2410/的資料夾下會有一個arch.c的檔案,此檔案中有一段程式如下
- MACHINE_START(QT2410, "QT2410(SMDK2410)")
- /* Maintainer: Joey Cheng <<a href=\"mailto:jemicheng@gmail.com\">jemicheng@gmail.com</a>> */
- .init_irq = qt2410_init_irq,
- .init_machine = qt2410_init_machine,
- .boot_params = 0x30000100,
- .timer = &qt2410_timer,
- MACHINE_END
當linux核心做初始化的動作時,至少會呼叫到3個architecture的初始化函式,分別為init_irq,init_machine和timer
所以我們為IRQ而改的檔案就很明確,就是arch/arm/mach-qt2410/irq.c
而IRQ的initial過程只有兩個步驟
<1>mask所有的中斷來源
<2>註冊中斷chip
在IRQ.c這邊其實可以看到4510與2410極大的不同點,4510的IRQ.c真的很簡單,它只有新增一個irq chip,並把所有的中斷編號都註冊到此chip
中斷chip在linux kernel只幹三件事,mask interrupt, unmask interrupt和ack interrupt, 簡單的irq chip使用方法如下
- struct irqchip qt2410_irq_level_chip = {
- .ack = qt2410_irq_maskack,
- .mask = qt2410_irq_mask,
- .unmask = qt2410_irq_unmask,
- };
而我們在寫driver時經由setup_irq或request_irq所註冊的中斷處理函式會由do_level_irq或do_edge_irq呼叫執行,註冊的範例如下
- for (irqno = 0; irqno < NR_IRQS; irqno++)
- {
- switch (irqno)
- {
-
-
- case nUART0_INT:
- case nUART1_INT:
- case nUART2_INT:
- case nADC_INT:
- set_irq_chip(irqno, &qt2410_irq_level_chip);
- set_irq_handler(irqno, do_level_IRQ);
- break;
- default:
- set_irq_chip(irqno, &qt2410_irq_chip);
- set_irq_handler(irqno, do_edge_IRQ);
- set_irq_flags(irqno, IRQF_VALID);
- }
- }
當然,2410 IRQ複雜的不只是一顆IRQ chip就可以handle了,就以uart為例,在處理uart tx或rx中斷時,還必需去讀取subpending這個register,並以讀取的結果判別我們要處理的是tx還是rx中斷,所以為了這個動作,必需再新增一個chip並註冊chained handler
真正處理uart tx,rx中斷的地方是在chained handler, chained handler的註冊方式如下
- set_irq_chained_handler(nUART0_INT, qt2410_irq_demux_uart0);
而我們為uart新增了一個interrupt chip,也必需新增uart tx, rx中斷編號,並註冊相關的函式- for (irqno = nUART0_RX0_INT; irqno <= nUART0_TX0_INT; irqno++)
- {
- set_irq_chip(irqno, &qt2410_irq_uart0);
- set_irq_handler(irqno, do_edge_IRQ);
- set_irq_flags(irqno, IRQF_VALID);
- }
所以IRQ的程式我們大概處理完了,接下來我會講解timer...待續
fw_printenv-control u-boot enviroment variables under linux (2009-05-12 16:35)
rpcapd與netcat-測試嵌入式系統的好工具 (2009-04-09 17:06)
udev-強大的device node管理系統 (2009-02-02 20:35)
Framebuffer兩三事-Test On QT2410 (2009-01-12 16:29)
UIO-Linux user space I/O driver (2008-12-15 14:50)
GDB-刺入bug心臟的寶劍 (2008-10-15 16:11)
Telnet daemon-RS232以外的選擇 (2008-10-03 18:57)
在嵌入式系統切換file system-以squashfs和jffs2為例 (2008-10-01 19:44)
Linux kernel module-進入系統核心的鑰匙 (2008-09-12 14:03)